86 lines
2.8 KiB
Groovy
86 lines
2.8 KiB
Groovy
apply plugin: 'digital.wup.android-maven-publish'
|
|
apply plugin: 'maven-publish'
|
|
apply from: file('../gradle/artifact-settings.gradle')
|
|
|
|
version = project.ext.versionName
|
|
group = project.ext.mapboxArtifactGroupId
|
|
|
|
publishing {
|
|
publications {
|
|
MapboxMapsSdkPublication(MavenPublication) {
|
|
from components.android
|
|
groupId this.group
|
|
artifactId project.ext.mapboxArtifactId
|
|
version this.version
|
|
|
|
afterEvaluate {
|
|
artifact(androidSourcesJar)
|
|
artifact(androidJavadocsJar)
|
|
}
|
|
|
|
pom.withXml {
|
|
final mainNode = asNode()
|
|
mainNode.appendNode('name', project.ext.mapboxArtifactTitle)
|
|
mainNode.appendNode('description', project.ext.mapboxArtifactTitle)
|
|
mainNode.appendNode('url', project.ext.mapboxArtifactUrl)
|
|
|
|
final licenseNode = mainNode.appendNode('licenses').appendNode('license')
|
|
licenseNode.appendNode('name', project.ext.mapboxArtifactLicenseName)
|
|
licenseNode.appendNode('url', project.ext.mapboxArtifactLicenseUrl)
|
|
licenseNode.appendNode('distribution', "repo")
|
|
|
|
final developerNode = mainNode.appendNode('developers').appendNode('developer')
|
|
developerNode.appendNode('id', project.ext.mapboxDeveloperId)
|
|
developerNode.appendNode('name', project.ext.mapboxDeveloperName)
|
|
|
|
final scmNode = mainNode.appendNode("scm")
|
|
scmNode.appendNode("connection", project.ext.mapboxArtifactScmUrl)
|
|
scmNode.appendNode("developerConnection", project.ext.mapboxArtifactScmUrl)
|
|
scmNode.appendNode("url", project.ext.mapboxArtifactUrl)
|
|
}
|
|
}
|
|
}
|
|
repositories {
|
|
maven {
|
|
name = "GitHubPackages"
|
|
url = project.ext.mapboxPackageRepository
|
|
credentials {
|
|
username = System.getenv("GITHUB_ACTOR")
|
|
password = System.getenv("GITHUB_TOKEN")
|
|
}
|
|
}
|
|
}
|
|
}
|
|
|
|
task androidJavadocs(type: Javadoc) {
|
|
source = android.sourceSets.main.java.sourceFiles
|
|
classpath = files(android.bootClasspath)
|
|
failOnError = false
|
|
}
|
|
|
|
task androidJavadocsJar(type: Jar, dependsOn: androidJavadocs) {
|
|
classifier = 'javadoc'
|
|
from androidJavadocs.destinationDir
|
|
}
|
|
|
|
task androidSourcesJar(type: Jar) {
|
|
classifier = 'sources'
|
|
from android.sourceSets.main.java.sourceFiles
|
|
}
|
|
|
|
tasks.withType(Javadoc) {
|
|
options.addStringOption('encoding', 'UTF-8')
|
|
options.addStringOption('docencoding', 'UTF-8')
|
|
options.addStringOption('charset', 'UTF-8')
|
|
}
|
|
|
|
afterEvaluate { project ->
|
|
android.libraryVariants.all { variant ->
|
|
tasks.androidJavadocs.doFirst {
|
|
classpath += files(variant.javaCompile.classpath.files)
|
|
}
|
|
}
|
|
}
|
|
|
|
|