d866b289cc
Co-authored-by: pre-commit-ci[bot] <66853113+pre-commit-ci[bot]@users.noreply.github.com> Co-authored-by: Bart Louwers <bart@emeel.net>
100 lines
3.6 KiB
GLSL
100 lines
3.6 KiB
GLSL
layout (location = 0) in vec2 a_pos;
|
|
layout (location = 1) in vec2 a_decimals_ed;
|
|
layout (location = 2) in vec2 a_normal2d;
|
|
out vec4 v_color;
|
|
|
|
layout (std140) uniform FillExtrusionDrawableUBO {
|
|
highp mat4 u_matrix;
|
|
highp vec2 u_pixel_coord_upper;
|
|
highp vec2 u_pixel_coord_lower;
|
|
highp float u_height_factor;
|
|
highp float u_tile_ratio;
|
|
// Interpolations
|
|
highp float u_base_t;
|
|
highp float u_height_t;
|
|
highp float u_color_t;
|
|
highp float u_pattern_from_t;
|
|
highp float u_pattern_to_t;
|
|
lowp float drawable_pad1;
|
|
};
|
|
|
|
layout (std140) uniform FillExtrusionTilePropsUBO {
|
|
highp vec4 u_pattern_from;
|
|
highp vec4 u_pattern_to;
|
|
highp vec2 u_texsize;
|
|
lowp float tileprops_pad1;
|
|
lowp float tileprops_pad2;
|
|
};
|
|
|
|
layout (std140) uniform FillExtrusionPropsUBO {
|
|
highp vec4 u_color;
|
|
highp vec3 u_lightcolor;
|
|
lowp float props_pad1;
|
|
highp vec3 u_lightpos;
|
|
highp float u_base;
|
|
highp float u_height;
|
|
highp float u_lightintensity;
|
|
highp float u_vertical_gradient;
|
|
highp float u_opacity;
|
|
highp float u_fade;
|
|
highp float u_from_scale;
|
|
highp float u_to_scale;
|
|
lowp float props_pad2;
|
|
};
|
|
|
|
#pragma mapbox: define highp float base
|
|
#pragma mapbox: define highp float height
|
|
#pragma mapbox: define highp vec4 color
|
|
|
|
void main() {
|
|
#pragma mapbox: initialize highp float base
|
|
#pragma mapbox: initialize highp float height
|
|
#pragma mapbox: initialize highp vec4 color
|
|
|
|
vec3 normal = vec3(a_normal2d / 16384.0, a_normal2d.x == 0.0 && a_normal2d.y == 0.0 ? 1.0 : 0.0);
|
|
|
|
base = max(0.0, base);
|
|
height = max(0.0, height);
|
|
|
|
float t = mod(a_decimals_ed.x, 2.0);
|
|
float z = t > 0.0 ? height : base;
|
|
vec2 decimals = unpack_float(floor(a_decimals_ed.x / 2.0)) / 128.0;
|
|
|
|
gl_Position = u_matrix * vec4(a_pos + decimals, z, 1);
|
|
|
|
// Relative luminance (how dark/bright is the surface color?)
|
|
float colorvalue = color.r * 0.2126 + color.g * 0.7152 + color.b * 0.0722;
|
|
|
|
v_color = vec4(0.0, 0.0, 0.0, 1.0);
|
|
|
|
// Add slight ambient lighting so no extrusions are totally black
|
|
vec4 ambientlight = vec4(0.03, 0.03, 0.03, 1.0);
|
|
color += ambientlight;
|
|
|
|
// Calculate cos(theta), where theta is the angle between surface normal and diffuse light ray
|
|
float directional = clamp(dot(normal, u_lightpos), 0.0, 1.0);
|
|
|
|
// Adjust directional so that
|
|
// the range of values for highlight/shading is narrower
|
|
// with lower light intensity
|
|
// and with lighter/brighter surface colors
|
|
directional = mix((1.0 - u_lightintensity), max((1.0 - colorvalue + u_lightintensity), 1.0), directional);
|
|
|
|
// Add gradient along z axis of side surfaces
|
|
if (normal.z == 0.0) {
|
|
// This avoids another branching statement, but multiplies by a constant of 0.84 if no vertical gradient,
|
|
// and otherwise calculates the gradient based on base + height
|
|
float fMin = mix(0.7, 0.98, 1.0 - u_lightintensity);
|
|
float factor = clamp((t + base) * pow(height / 150.0, 0.5), fMin, 1.0);
|
|
directional *= (1.0 - u_vertical_gradient) + (u_vertical_gradient * factor);
|
|
}
|
|
|
|
// Assign final color based on surface + ambient light color, diffuse light directional, and light color
|
|
// with lower bounds adjusted to hue of light
|
|
// so that shading is tinted with the complementary (opposite) color to the light color
|
|
v_color.r += clamp(color.r * directional * u_lightcolor.r, mix(0.0, 0.3, 1.0 - u_lightcolor.r), 1.0);
|
|
v_color.g += clamp(color.g * directional * u_lightcolor.g, mix(0.0, 0.3, 1.0 - u_lightcolor.g), 1.0);
|
|
v_color.b += clamp(color.b * directional * u_lightcolor.b, mix(0.0, 0.3, 1.0 - u_lightcolor.b), 1.0);
|
|
v_color *= u_opacity;
|
|
}
|