plugins {
    id 'org.jmailen.kotlinter'
    id 'com.android.application'
    id 'org.jetbrains.kotlin.android'
    id 'org.jetbrains.kotlin.plugin.serialization' version '1.9.21'
}

apply from: "${rootDir}/gradle/native-build.gradle"

def obtainTestBuildType() {
    def result = "debug";

    if (project.hasProperty("testBuildType")) {
        result = project.getProperties().get("testBuildType")
    }

    result
}

android {
    compileSdkVersion androidVersions.compileSdkVersion

    defaultConfig {
        applicationId "org.maplibre.testapp"
        minSdkVersion androidVersions.minSdkVersion
        targetSdkVersion androidVersions.targetSdkVersion
        versionCode 14
        versionName "6.0.1"
        testInstrumentationRunner "org.maplibre.android.InstrumentationRunner"
        multiDexEnabled = true
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }

    kotlinOptions {
        jvmTarget = "1.8"
    }

    nativeBuild(["example-custom-layer"])
    packagingOptions {
        resources {
            excludes += ['META-INF/LICENSE.txt', 'META-INF/NOTICE.txt', 'LICENSE.txt']
        }
    }


    buildTypes {
        debug {
            jniDebuggable true
            debuggable true
            testCoverageEnabled true
            minifyEnabled false
            shrinkResources false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
        release {
            minifyEnabled true
            shrinkResources true
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
            testProguardFiles 'test-proguard-rules.pro'
            signingConfig signingConfigs.debug
        }
    }

    testBuildType obtainTestBuildType()

    flavorDimensions += "renderer"
    productFlavors {
        create("legacy") {
            dimension = "renderer"
        }
        create("drawable") {
            dimension = "renderer"
        }
    }

    buildFeatures {
        viewBinding = true
    }

    namespace 'org.maplibre.android.testapp'
    testNamespace 'org.maplibre.testapp.test'
    lint {
        abortOnError false
        baseline file('lint-baseline-local.xml')
        checkAllWarnings true
        disable 'MissingTranslation', 'GoogleAppIndexingWarning', 'UnpackedNativeCode', 'IconDipSize', 'TypographyQuotes'
        warningsAsErrors true
    }
}

dependencies {
    implementation project(':MapboxGLAndroidSDK')
    implementation dependenciesList.mapboxJavaTurf

    implementation dependenciesList.supportAppcompatV7
    implementation dependenciesList.supportRecyclerView
    implementation dependenciesList.supportDesign
    implementation dependenciesList.supportConstraintLayout
    implementation 'org.jetbrains.kotlinx:kotlinx-serialization-json:1.6.0'

    implementation dependenciesList.multidex

    implementation dependenciesList.timber

    implementation dependenciesList.okhttp3

    debugImplementation dependenciesList.leakCanary

    androidTestImplementation dependenciesList.supportAnnotations
    androidTestImplementation dependenciesList.testRunner
    androidTestImplementation dependenciesList.testRules
    androidTestImplementation dependenciesList.testEspressoCore
    androidTestImplementation dependenciesList.testEspressoIntents
    androidTestImplementation dependenciesList.testEspressoContrib
    androidTestImplementation dependenciesList.testUiAutomator
    androidTestImplementation dependenciesList.appCenter
    androidTestImplementation 'androidx.test.ext:junit:1.1.5'
    androidTestImplementation 'androidx.test:core-ktx:1.5.0'

}

apply from: "${rootDir}/gradle/gradle-make.gradle"
apply from: "${rootDir}/gradle/gradle-config.gradle"
apply from: "${rootDir}/gradle/gradle-checkstyle.gradle"
apply from: "${rootDir}/gradle/gradle-lint.gradle"